Sphères du 19.8.2017

soland · August 2017

Trois boules mutuellement tangentes sont posées sur le sol.
Les distances respectives des trois points de contact avec
le sol sont 75, 102 et 117.

L'espace délimité par les trois boules et le sol est-il suffisant pour
accueillir (merci Messieurs les Académiciens de 1694)
une sphère de diamètre 32 ?

GaBuZoMeu · August 2017

Ça suffit même pour accueillir une sphère de rayon 34.

soland · August 2017

Vu de dessous. La petite sphère a un rayon de 16 66414

Math Coss · August 2017

C'est curieux, je ne suis d'accord avec aucun de vous deux. Voici quatre sphères tangentes deux à deux posées sur un plan. Voici le code :

R = [75,102,117]
eq = (1/x+sum(1/r for r in R)) ^2 - 3*(sum(1/r^2 for r in R)+1/x^2)
rays = (eq*x^2).roots()
r4 = rays[0][0]
R+= [r4]
print [r.n() for r in R]

a = arccos((R[0]*R[1]+R[0]*R[2]-R[1]*R[2])/2/R[0]/sqrt(R[1]*R[2]))
d13 = 2*sqrt(R[0]*R[2])

beta = arccos((R[0]*R[1]+R[0]*R[3]-R[1]*R[3])/2/R[0]/sqrt(R[1]*R[3]))
d14 = 2*sqrt(R[0]*R[3])

O = [(0,0,R[0]), (2*sqrt(R[0]*R[1]),0,R[1]), (d13*cos(a),d13*sin(a),R[2]), (d14*cos(beta),d14*sin(beta),R[3])]

var('uu vv')
clr = ['red','green','blue','purple']
G = add(sphere(O[j],R[j],color=clr[j]) for j in range(4))
b = G.bounding_box()
P = parametric_plot3d((uu,vv,0),(uu,b[0][0],b[1][0]),(vv,b[0][1],b[1][1]), color="yellow",opacity=.3)

(G+P).show(aspect_ratio=1,frame=0)

Le rayon de la petite sphère pourpre est
$$\frac{156683475}{182701}-\frac{49725}{182701}\sqrt{9197997} \simeq 32,\!16.$$

Autrement dit, le rayon optimal est légèrement supérieur à 32 (et pas 16) mais strictement inférieur à 34. Ledit rayon a été calculé avec le théorème de Soddy-Gosset en cherchant $R_4$ tel que
$$\left(\frac{1}{R_1}+\frac{1}{R_2}+\frac{1}{R_3}+\frac{1}{R_4}\right)^2-3\left(\frac{1}{R_1^2}+\frac{1}{R_2^2}+\frac{1}{R_3^2}+\frac{1}{R_4^2}\right)=0,$$
avec $(R_1,R_2,R_3)=(75,102,117)$.

Edit: Rectification de deux fautes de frappe + ajout du code complet. 66416

GaBuZoMeu · August 2017

Je confirme. Une sphère de rayon 34cm trouve sa place. Dessin Geogebra avec cotes (divisées par 10). 66418

GaBuZoMeu · August 2017

Mon code Sagemath :

R.<a,b,c,r,s,t,x,y,z>=PolynomialRing(QQ,9)
I1=R.ideal([a^2-4*r*s, (b-a)^2+c^2-4*s*t, b^2+c^2-4*t*r])
I2=R.ideal([2*r*s-75*(r+s), 2*s*t-102*(s+t),2*t*r-117*(t+r)])
I3=R.ideal([x^2+y^2+(z-r)^2-(z+r)^2, (x-a)^2+y^2+(z-s)^2-(z+s)^2, (x-b)^2+(y-c)^2+(z-t)^2-(z+t)^2])
I=I1+I2+I3
J=R.ideal(r*s*t)
K,d=I.saturation(J)
L=K.variety(AA)
filter( lambda sol : sol[a] >0 and sol[c]>0, L)

La sortie :

[{z: 34.30607725899023?, y: 68.31147279018973?, x: 81.8323782723972?, c: 230.7069129267709?, b: 113.07871109214374?, t: 199.2985971943888?, a: 150.6709661815213?, s: 68.5389386629911?, r: 82.80599500416320?},
 {z: 394.4914525848530?, y: -328.8642718395363?, x: 150.0443924815495?, c: 230.7069129267709?, b: 113.07871109214374?, t: 199.2985971943888?, a: 150.6709661815213?, s: 68.5389386629911?, r: 82.80599500416320?}]

On peut deviner à quoi correspond la deuxième solution.

PS. J'ajoute quelques explications : une sphère de centre $(0,0,r)$ de rayon $r$, une de centre $(a,0,s)$ de rayon $s$, une de centre $(b,c,t)$ de rayon $t$. Les équations de l'idéal $I_1$ expriment que ces sphères sont tangentes extérieurement deux à deux. Les équations de l'idéal $I_2$ expriment que les points de tangence sont aux hauteurs prescrites.
Une dernière sphère de centre $(x,y,z)$ de rayon $z$. Les équations de l'idéal $I_3$ expriment que cette sphère est tangente extérieurement aux trois autres.
On sature l'idéal $I_1+I_2+I_3$ par rapport à $rst$ pour se débarrasser des solutions parasites avec $r,s,t$ nuls. On trouve les solutions réelles algébriques avec $a>0$, $c>0$.

PS2. @Math Coss : ton erreur est facile à trouver, tu as pris les cotes 75, 102 et 117 pour les rayons des sphères (erreur de lecture d'énoncé). Pour soland, je ne peux pas tracer son erreur puisqu'il n'a produit rien d'autre qu'un dessin sans information.

Math Coss · August 2017

Ah ! Merci ! En ajoutant le calcul pédestre des rayons :

contact = [75,102,117]
var('a b c')
S = [2*a*b-contact[0]*(a+b),2*b*c-contact[1]*(b+c),2*c*a-contact[2]*(c+a)]
sols = solve(S,[a,b,c])[1]
R = [l.subs(sols) for l in [a,b,c]]

ça donne bien pour le quatrième rayon :
$$R_4=\frac{156683475}{730804}-\frac{49725}{730804} \, \sqrt{7005585}\simeq 34.3060772589902$$
et une figure très semblable à la précédente, que je ne reproduis pas.

GaBuZoMeu · August 2017

Quand on demande à Sage d'écrire les nombres algébriques trouvés pour $z$ au moyen de radicaux il répond effectivement

-49725/730804*sqrt(7005585) + 156683475/730804
49725/730804*sqrt(7005585) + 156683475/730804

Math Coss · August 2017

J'apprends en m'amusant : en repartant du code de GaBuZoMeu, voici en principe une preuve de la relation de Descartes entre les rayons de cinq sphères mutuellement tangentes lorsque l'une d'entre elles est un plan. On reprend $I_1$ et $I_3$ mais on abandonne $I_2$ qui exprime les conditions sur les hauteurs des points de contacts, puis on élimine les variables correspondant aux coordonnées des centres pour obtenir les relations portant uniquement sur les rayons (plus besoin de saturer) :

R.<a,b,c,r,s,t,x,y,z>=PolynomialRing(QQ,9)
I1=R.ideal([a^2-4*r*s, (b-a)^2+c^2-4*s*t, b^2+c^2-4*t*r])
I3=R.ideal([x^2+y^2+(z-r)^2-(z+r)^2, (x-a)^2+y^2+(z-s)^2-(z+s)^2, (x-b)^2+(y-c)^2+(z-t)^2-(z+t)^2])
I=I1+I3
L=I.elimination_ideal([x,y,a,b,c])
print L
Descartes = ((1/r+1/s+1/t+1/z)^2-3*(1/r^2+1/s^2+1/t^2+1/z^2)).numerator()
print L == R.ideal(Descartes)

On obtient :

Ideal (r^2*s^2*t^2 - r^2*s^2*t*z - r^2*s*t^2*z - r*s^2*t^2*z + r^2*s^2*z^2 - r^2*s*t*z^2 - r*s^2*t*z^2 + r^2*t^2*z^2 - r*s*t^2*z^2 + s^2*t^2*z^2) of Multivariate Polynomial Ring in a, b, c, r, s, t, x, y, z over Rational Field
True

Évidemment, en 1694, on procédait sans doute autrement.

GaBuZoMeu · August 2017

1694 est la date de la première édition du dictionnaire de l'Académie Françoise.

Math Coss · August 2017

Ah ! Pardon, je pensais que c'était un défi lancé par un académicien des sciences.

Cela dit, je n'arrive pas à adapter la preuve de la relation de Descartes pour 5 sphères de rayon fini. Plus précisément, le code suivant ne répond pas en quelques minutes. Est-ce que le passage de 9 à 15 variables est insurmontable en termes de complexité ? ou est-ce qu'il y a une erreur ?

R.<a3,a4,a5,b3,b4,b5,c2,c3,c4,c5,r1,r2,r3,r4,r5> = PolynomialRing(QQ,15)
a1,b1,a2,b2,c1 = 0,0,0,0,0
a = [a1,a2,a3,a4,a5]
b = [b1,b2,b3,b4,b5]
c = [c1,c2,c3,c4,c5]
r = [r1,r2,r3,r4,r5]
C = lambda j,k: (a[j]-a[k])^2+(b[j]-b[k])^2+(c[j]-c[k])^2-(r[j]+r[k])^2
L = [C(j,k) for j in range(4) for k in range(j+1,5)]
I = R.ideal(L)
J = I.elimination_ideal([a3,a4,a5,b3,b4,b5,c2,c3,c4,c5])

soland · August 2017

Je suis tombé, un accident sans gravité (plutôt avec, lol).
Calculs suivront ce 20 ou le 21.8

GaBuZoMeu · August 2017

Accident de moto ? Remets-toi bien !

soland · August 2017

Je n'ai pas eu le courage de relire tout ce qui précède.
On voudra bien me pardonner les redites, s'il y en a.

Soit S$_i$ les trois sphères, c$_i$ leurs centres et $r_i$ leurs rayons.
Le plan vertical contenant c$_i$ et c$_j$ coupe la figure donnée en deux cercles tangents
de rayons $r_i$ et $r_j$ et une tangente extérieure commune. La distance des points de contact est
$2\sqrt{r_ir_j}$ . On trouve donc les rayons des sphères en résolvant
$$\begin{array}{rll}
2\sqrt{r_1r_2} &=75 & r_1=2925/68\\
2\sqrt{r_2r_3} &=102 \qquad\text{ce qui donne} \qquad & r_2= 425/13\\
2\sqrt{r_3r_1} &=117 & r_3=1989/25\\
\end{array}$$
Le théorème de Descartes-Beecroft-Soddy-Coxeter en dimension 3 donne, pour la petite sphère additionnelle de rayon $r_0$,
$$\begin{array}{c}
(0 + r_0^{-1} + r_1^{-1} + r_2^{-1} + r_3^{-1})^2 = 3\cdot(0^2 + r_0^{-2} + r_1^{-2} + r_2^{-2} + r_3^{-2}) \qquad\text{et} \\
r_0 = 49\,725(1651-840\sqrt{3})/609\,001 \approx 16.0097
\end{array}$$ 66430